Effectful bindings for the HUnit library.

Overview

This library provides HUnit's Assertion and Test types, along with all the standard test combinators and operators, expressed in terms of the HUnit effect. This effect allows you to intersperse test assertions with arbitrary other effects.

Example usage

Suppose we wish to test stateful operations on an account balance:

deposit :: (State Int :> es) => Int -> Eff es ()
deposit amount = modify (+ amount)

balance :: (State Int :> es) => Eff es Int
balance = get

withdraw :: (State Int :> es) => Int -> Eff es Bool
withdraw amount = do
    funds <- balance
    if funds < amount
        then pure False
        else do
            put $ funds - amount
            pure True

Use TestCase to define individual unit tests, and TestLabel to give them a description:

depositsAccumulate :: (State Int :> es, HUnit :> es) => Test es
depositsAccumulate = TestLabel "deposits accumulate" . TestCase $ do
    deposit 100
    deposit 50
    funds <- balance
    funds @?= 150

withdrawalsAreChecked :: (State Int :> es, HUnit :> es) => Test es
withdrawalsAreChecked = TestLabel "withdrawals are checked" . TestCase $ do
    withdraw 30 >>= (@? "Insufficient funds")
    funds <- balance
    funds @?= 120

Group multiple test cases with TestList:

accountTests :: (State Int :> es, HUnit :> es) => Test es
accountTests = TestLabel "account tests" $ TestList [depositsAccumulate, withdrawalsAreChecked]

Finally, run the tests with runTestTTAndExit, and use runHUnit to resolve the effect:

main :: IO ()
main = runEff . runHUnit . evalState @Int 0 $ runTestTTAndExit accountTests

Alternatively, use runTestTT to handle the test results manually.